利用XSLT把ADO記錄集轉(zhuǎn)換成XML

2019-11-18 16:39:36

字體：大中小

供稿：網(wǎng)友

孟憲會

由于xml（可擴(kuò)展標(biāo)記語言：eXtensible Markup Language）真正的平臺無關(guān)性，它正在逐漸成為數(shù)據(jù)傳輸?shù)闹饕橘|(zhì)。XML是一種自描述的語言，數(shù)據(jù)本身就已經(jīng)包含了元數(shù)據(jù)，即關(guān)于數(shù)據(jù)本身的信息。例如：“孟子E章1757281793923net_lover1807581793923”這組數(shù)據(jù)，從字面很難看出它代表什么意思，也不清楚它有幾個(gè)數(shù)據(jù)段組成，但是，如果用XML來做如下的描述，我們就可以清楚地看到每個(gè)數(shù)據(jù)段所代表的含義：

<PersonData>
<Person>
   <姓名>孟子E章</姓名>
   <身高>175</身高>
   <體重>72</體重>
   <電話>81793923</電話>
</Person>
<Person>
   <姓名>net_lover</姓名>
   <身高>180</身高>
   <體重>75</體重>
   <電話>81793923</電話>
</Person>
</PersonData>
      從上面的一段XML中，我們不但可以清楚地看到每一個(gè)數(shù)據(jù)代表的是什么意思了，而且還可以知道數(shù)據(jù)的分割位置。在我們平常的應(yīng)用中，我們得到的結(jié)果可能是數(shù)組、集合或記錄集的表現(xiàn)形式，我們該如何把它們轉(zhuǎn)換成自描述的XML格式的數(shù)據(jù)呢？從數(shù)據(jù)形式上看，XML是簡單的純字符串的文本格式，字符串在傳遞時(shí) 是非常簡單、快速而且是容易的，數(shù)組在通過引用進(jìn)行傳遞時(shí)有時(shí)是很慢的，而且處理起來很麻煩，而集合和記錄集都是對象，在處理時(shí)會導(dǎo)致計(jì)算機(jī)性能的下降，并且這些對象都是與特定的平臺相關(guān)聯(lián)的，這就要求平臺有內(nèi)建的處理機(jī)制來處理對象的操作。XML已經(jīng)是W3C的標(biāo)準(zhǔn)，是平臺無關(guān)的，我們的計(jì)算機(jī)的唯一要求就是能夠處理簡單的XML字符串，即XML解析器，它能夠解析XML字符串，能夠通過一種接口很容易地把數(shù)據(jù)分解成一個(gè)個(gè)獨(dú)立的數(shù)據(jù)段，以便我們能夠進(jìn) 行訪問。XML解析器都很小，性能也很好，在每種平臺上都可以找到。一旦我們接收到XML數(shù)據(jù)并把它解析成上面的例子的樣式后，我們就可以通過XSLT （eXstensible Stylesheet Language Transformations）把他們轉(zhuǎn)換成不同的表現(xiàn)形式。利用XML的數(shù)據(jù)格式進(jìn)行數(shù)據(jù)傳輸，將會使我們編寫應(yīng)用程序代碼的工作更簡單輕松，而且具有良好的可伸縮性。
下面，我們就看看如何來轉(zhuǎn)換我們的數(shù)據(jù)。我們的例子是在Microsoft Windows 2000,IIS5,MSXML3和ADO2.6下編寫的，樣例數(shù)據(jù)采用Microsoft SQL Server7.0自帶的Northwind示例數(shù)據(jù)庫。之所以采用SQL Server7而不采用支持XML的SQL Server2000，是考慮到通用性的原則，我們的目的是：處理不同類型的數(shù)據(jù)源得到的記錄集，而不僅僅是象SQL Server2000那樣的支持XML輸出的數(shù)據(jù)源。使用ADO，是因?yàn)樗问蕉鄻?，可以處理不同類型的?shù)據(jù)源；使用XML，是因?yàn)樗軌蚩焖賯鬏敽徒?析。但本例的處理方法也適合在任何具有Micrsoft XML解析器，ADO2.5或以上版本的Windows,IIS,SQL Server的環(huán)境中。
為簡單起見，我們僅選擇單價(jià)小于等于20美圓，庫存大于等于20，產(chǎn)品名稱小于等于6個(gè)字符的產(chǎn)品：

<%
Dim objRecordset
Set objRecordset = Server.CreateObject("ADODB.Recordset")
objRecordset.open _
      "SELECT PRoductName, UnitPrice, UnitsInStock " _
          & "FROM Products " _
          & "WHERE UnitPrice <= 20 " _
          & "AND UnitsInStock >= 20 " _
          & "AND LEN(ProductName) <= 6 " _
          & "ORDER BY ProductName", _
      "Provider=SQLOLEDB;" _
          & "Data Source=SomeSQLServer;" _
          & "Initial Catalog=Northwind;" _
          & "User ID=MyUserName;" _
          & "PassWord=MyPassword;"
%>
現(xiàn)在，我們就用3種方式把我們得到的記錄集轉(zhuǎn)換成XML格式。
首先，我們可以遍歷整個(gè)記錄集，采用XML DOM(Document Object Model)，建立XML節(jié)點(diǎn)樹：

<%
Dim objXMLDOM, objRootNode, objNode
Set objXMLDOM = Server.CreateObject("MSXML2.DOMDocument")

Set objRootNode = objXMLDOM.createElement("xml")
objXMLDOM.documentElement = objRootNode

Do While NOT objRecordset.EOF
      Set objRowNode = objXMLDOM.createElement("row")
      Set objNode = objXMLDOM.createElement("ProductName")
      objNode.text = objRecordset.Fields.Item("ProductName").Value
      objRowNode.appendChild(objNode)

      Set objNode = objXMLDOM.createElement("UnitPrice")
      objNode.text = objRecordset.Fields.Item("UnitPrice").Value
      objRowNode.appendChild(objNode)

      Set objNode = objXMLDOM.createElement("UnitsInStock")
      objNode.text = objRecordset.Fields.Item("UnitsInStock").Value
      objRowNode.appendChild(objNode)

      objRootNode.appendChild(objRowNode)

      objRecordset.MoveNext
Loop

Set objNode = Nothing
Set objRowNode = Nothing
Set objRootNode = Nothing

Set objRecordset = Nothing
%>

現(xiàn)在，我們就得到了一個(gè)XML DOM對象。這種方法對于記錄集很大時(shí)性能并不理想，因?yàn)橄到y(tǒng)內(nèi)存中要同時(shí)保存ADO記錄集對象和XML DOM對象。
第二個(gè)辦法，遍歷記錄集，直接生成XML字符串本身：

<%
Dim strXML
strXML = "<xml>"
objRecordset.MoveFirst
Do While NOT objRecordset.EOF
      strXML = strXML & "<row>"
      strXML = strXML & "<ProductName>" _
          & objRecordset.Fields.Item("ProductName").Value _
          & "</ProductName>"
      strXML = strXML & "<UnitPrice>" _
          & objRecordset.Fields.Item("UnitPrice").Value _
          & "</UnitPrice>"
      strXML = strXML & "<UnitsInStock>" _
          & objRecordset.Fields.Item("UnitsInStock").Value _
          & "</UnitsInStock>"
      strXML = strXML & "</row>"
      objRecordset.MoveNext
Loop
strXML = strXML & "</xml>"
Set objRecordset = Nothing
%>

但是，以上兩種方法最大的缺陷是不能夠重用代碼，我們把節(jié)點(diǎn)的名字都寫死了，如果我們進(jìn)行不同字段的查詢，我們還必須手動更改我們的代碼，以滿足不同節(jié)點(diǎn)的需要。我們下面的方法將變得更加通用。
第三種方法：可重用的方法。

<%
Dim strXML
strXML = "<xml>"
objRecordset.MoveFirst
Do While NOT objRecordset.EOF
      strXML = strXML & "<row>"
      For Each varItem In objRecordset.Fields
          strXML = strXML _
              & "<" & varItem.name & ">" _
              & varItem.value _
              & "</" & varItem.name & ">"
      Next
      strXML = strXML & "</row>"
      objRecordset.MoveNext
Loop
strXML = strXML & "</xml>"
Set objRecordset = Nothing
%>

一個(gè)更有效的方法，我們可以直接利用記錄集內(nèi)建的save方法，它能夠自動地把記錄集的內(nèi)容轉(zhuǎn)換成XML格式，我們調(diào)用save方法后，我們就可以立即釋放內(nèi)存中的記錄集對象實(shí)例。 save方法有兩個(gè)參數(shù)：一個(gè)是XML要保存的地方，一個(gè)是指示符，標(biāo)明數(shù)據(jù)以何種格式保存。我們可以把數(shù)據(jù)保存成XML DOM對象（ADO STREAM對象），也可以直接保存成asp RESPONSE對象，為通用起見，我們保存成XML DOM，第二個(gè)參數(shù)用adPersistXML ADO常量。方法如下：

<%
Const adPersistXML = 1
Dim objXMLDOM
Set objXMLDOM = Server.CreateObject("MSXML2.DOMDocument.3.0")
objRecordset.save objXMLDOM, adPersistXML
Set objRecordset = Nothing
%>

這種方法方便快捷，而且不容易出錯(cuò)，對不同的查詢，也不用手動更改節(jié)點(diǎn)名字。但是，這種方法產(chǎn)生的XML不夠簡潔，看看它產(chǎn)生的結(jié)果：

<xml
    xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882"
    xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882"
    xmlns:rs="urn:schemas-microsoft-com:rowset"
    xmlns:z="#RowsetSchema">

<s:Schema id="RowsetSchema">

    <s:ElementType
        name="row"
        content="eltOnly"
        rs:CommandTimeout="30">

        <s:AttributeType
            name="ProductName"
            rs:number="1"
            rs:writeunknown="true">

            <s:datatype
                dt:type="string"
                dt:maxLength="40"
                rs:maybenull="false"/>
        </s:AttributeType>

        <s:AttributeType
            name="UnitPrice"
            rs:number="2"
            rs:nullable="true"
            rs:writeunknown="true">

            <s:datatype
                dt:type="number"
                rs:dbtype="currency"
                dt:maxLength="8"
                rs:precision="19"
                rs:fixedlength="true"/>
        </s:AttributeType>

        <s:AttributeType
            name="UnitsInStock"
            rs:number="3"
            rs:nullable="true"
            rs:writeunknown="true">

            <s:datatype
                dt:type="i2"
                dt:maxLength="2"
                rs:precision="5"
                rs:fixedlength="true"/>
        </s:AttributeType>

<s:extends type="rs:rowbase"/>

</s:ElementType>

</s:Schema>

<rs:data>

    <z:row
        ProductName="Chai"
        UnitPrice="18"
        UnitsInStock="39"/>

    <z:row
        ProductName="Konbu"
        UnitPrice="6"
        UnitsInStock="24"/>

    <z:row
        ProductName="Tofu"
        UnitPrice="23.25"
        UnitsInStock="35"/>

</rs:data>

</xml>

ADO 自動產(chǎn)生的XML包含了schema信息，它描述這個(gè)XML里允許有什么節(jié)點(diǎn)和屬性以及采用何種數(shù)據(jù)類型，而且數(shù)據(jù)節(jié)點(diǎn)也增加了名稱空間。schema信息在需要數(shù)據(jù)驗(yàn)證的地方或進(jìn)行更復(fù)雜的處理或許很有用，但是，大多數(shù)情況下，我們使用的是瘦客戶機(jī)，我們不需要schema信息。我們可以利用XSLT來分離出我們想要的信息，去掉多余的信息。因此，我們編寫下面的“ DataCleaner.xsl”:

<?xml version="1.0"?>
<xsl:stylesheet version="1.0"
      xmlns:xsl="      xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882"
      xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882"
      xmlns:rs="urn:schemas-microsoft-com:rowset"
      xmlns:z="#RowsetSchema">

<xsl:output omit-xml-declaration="yes"/>
<xsl:template match="/">
      <xsl:element name="xml">
          <xsl:for-each select="/xml/rs:data/z:row">
              <xsl:element name="row">
                  <xsl:for-each select="@*">
                      <xsl:element name="{name()}">
                          <xsl:value-of select="."/>
                      </xsl:element>
                  </xsl:for-each>
              </xsl:element>
          </xsl:for-each>
      </xsl:element>
</xsl:template>

</xsl:stylesheet>

這個(gè)XSLT具有可重用的特性，對于不同的查詢結(jié)果都適用，下面就是如何使用這個(gè)XSLT的例子：

<%
Dim strCleanXML, objXMLDOM_XSLT

Set objXMLDOM_XSLT = CreateObject("MSXML2.DOMDocument")
objXMLDOM_XSLT.load(Server.MapPath("DataCleaner.xsl"))
strCleanXML = objXMLDOM.transformNode(objXMLDOM_XSLT)

Set objXMLDOM = Nothing
Set objXMLDOM_XSLT = Nothing
%>

經(jīng)過上面的處理以后，strClaenXML就是我們所想要的XML字符串了。

<xml>
      <row>
          <ProductName>Chai</ProductName>
          <UnitPrice>18</UnitPrice>
          <UnitsInStock>39</UnitsInStock>
      </row>
      <row>
          <ProductName>Konbu</ProductName>
          <UnitPrice>6</UnitPrice>
          <UnitsInStock>24</UnitsInStock>
      </row>
</xml>

上面這種格式的XML字符串是我們經(jīng)常見到的節(jié)點(diǎn)集的樣式，如果您不想把字段處理成節(jié)點(diǎn)，而把它處理成屬性節(jié)點(diǎn)，那么我們只需對DataCleaber.xsl稍加改動即可：