在Windows主機上定時備份遠程VPS(CentOS)數據的批處理

2024-07-09 22:47:54

字體：大中小

來源：轉載

供稿：網友

不過折騰 VPS 之后，就不只是要備份 MySQL 了，一些獨立的站點數據也是需要備份的。
如果有靠譜的第三方 Linux 主機或類似 Amazon 的云存儲，那就簡單多了，Linux - Linux 的備份很方便。
不過我想在自己的 Windows7 下每天/周運行一次備份，就有了這個小工具。

大概的想法如下：
使用 Putty 自帶的 plink.exe 連接到 VPS 上，運行備份并退出登錄；
接著使用 Putty 自帶的 pscp.exe 將備份復制到本機；
添加一個計劃任務，每天/周自動運行一次，實現定時備份。

復制代碼代碼如下:

Windows 下負責觸發備份的 index.bat
@echo off & setlocal ENABLEEXTENSIONS

:: 這里只是 SSH 連接和備份路徑配置信息
:: 請同時修改同目錄下 linux 文件中要備份的路徑和 MySQL 數據庫

:: SSH 相關信息
set SERVER=192.168.1.100
set PORT=22
set USER=root
set PASSWORD=password

:: 和同目錄下 linux 文件中配置的路徑對應
set BACKUP_PATH=/root/backup

:: 備份要下載到的本機位置（會自動創建）
set SAVE_PATH=D:/Backup/

:: ---------- 配置結束，以下請勿修改 ----------

:: 運行時變量
set EXE_SSH=%~dp0/exe/plink.exe
set EXE_SCP=%~dp0/exe/pscp.exe
set LINUX=%~dp0/linux

set YEAR=%date:~0,4%
set MONTH=%date:~5,2%
set DAY=%date:~8,2%
set TRUE_PATH=%SAVE_PATH%%YEAR%-%MONTH%-%DAY%/

:: 創建備份路徑
echo Creating Backup Dir...
if not exist %TRUE_PATH% (
mkdir %TRUE_PATH% 2>nul
)
if not exist %TRUE_PATH% (
echo Backup path: %TRUE_PATH% not exists, create dir failed.
goto exit
)
echo Creating Backup Dir... Done.

:: 生成備份目錄和文件
echo Connecting to remote server and creating backups...
%EXE_SSH% -C %USER%@%SERVER% -P %PORT% -pw %PASSWORD% -m %LINUX% 2>nul
echo Connecting to remote server and creating backups... Done.

:: 下載備份
echo Downloading backups...
%EXE_SCP% -pw %PASSWORD% -P %PORT% %USER%@%SERVER%:%BACKUP_PATH%/*.* %TRUE_PATH%
echo Downloading backups... Done.

:exit
echo Exit

由 index.bat 調用的 Linux 端命令
復制代碼代碼如下:

#!/bin/bash

PATH=/usr/local/sbin:/usr/bin:/bin

# ---------- 配置項，不要最后的 / ----------

# 備份文件存儲的路徑，請與 index.bat 中的 BACKUP_PATH 保持一致
BACKUP_PATH=/root/backup

# 要備份的文件或目錄，多個以空格分隔
FILES="/www/cmstop /www/dbpma"

# mysqldump 可執行文件的全路徑(如果可以直接執行 mysqldump 可不用全路徑)
MYSQLDUMP=mysqldump

# 要備份的 MySQL 數據庫，多個以空格分隔
DATABASES="mysql test"

# MySQL 用戶名
USER=root

# MySQL 密碼
PASSWD=

# ---------- 配置項結束，下面的不用修改 ----------

上一篇：Sysbench多線程性能測試工具

下一篇：IP處理函數inet_aton()和inet_ntoa()使用說明

發表評論

共有條評論