通過數組給您的文件排序

2020-07-27 13:36:23

字體：大中小

來源：轉載

供稿：網友

當您使用FILESYSTEMOBJECT對象獲得某個目錄下的文件列表的時候，你有沒有發(fā)現無法控制它們的排序方式，比如按照名字排序，按照擴展名排序，按照文件大小排序等等，讓我們試著用數組給它們排排序兒。

如果您想通過名字排序，那將是非常簡單的，但是假如你想通過文件大小或者文件創(chuàng)立時間等等來排序的時候，那么將有點麻煩。我們將通過二維數組做到這一點。

下面的代碼演示了如何通過選擇排序方式達到的我們目的，單擊排序，點兩次就反著排了。

<HTML>
<HEAD>
<TITLE>文件排序演示</TITLE>
</HEAD>
<BODY>
<%
' 設定一個演示目錄，：）
CONST DIRECTORY = "/"
' 用常數定義排序方式
CONST FILE_NAME = 0 '按照名字排序……依次類推
CONST FILE_EXT = 1
CONST FILE_TYPE = 2
CONST FILE_SIZE = 3
CONST FILE_CREATED = 4
CONST FILE_MODIFIED = 5
CONST FILE_ACCESSED = 6
'獲得排序命令，默認為按照名字排序
req = Request("sortBy")
If Len(req) < 1 Then sortBy = 0 Else sortBy = CInt(req)
req = Request("priorSort")
If Len(req) < 1 Then priorSort = -1 Else priorSort = CInt(req)
'設置倒序
If sortBy = priorSort Then
reverse = true
priorSort = -1
Else
reverse = false
priorSort = sortBy
End If
' 接下來開始我們真正的代碼了。。。
path = Server.MapPath(DIRECTORY)
Set fso = CreateObject("Scripting.FileSystemObject")
Set theCurrentFolder = fso.GetFolder(path)
Set curFiles = theCurrentFolder.Files
' 給這些文件做一個循環(huán)
Dim theFiles()
ReDim theFiles(500) ' 我隨便定的一個大小
currentSlot = -1 ' start before first slot
' 我們將文件的所有相關信息放到數組里面
For Each fileItem in curFiles
fname = fileItem.Name
fext = InStrRev(fname, ".")
If fext < 1 Then fext = "" Else fext = Mid(fname,fext+1)
ftype = fileItem.Type
fsize = fileItem.Size
fcreate = fileItem.DateCreated
fmod = fileItem.DateLastModified
faccess = fileItem.DateLastAccessed
currentSlot = currentSlot + 1
If currentSlot > UBound(theFiles) Then
ReDim Preserve theFiles(currentSlot + 99)
End If
' 放到數組里
theFiles(currentSlot) = Array(fname,fext,ftype,fsize,fcreate,fmod,faccess)
Next
' 現在都在數組里了，開始下一步
fileCount = currentSlot ' 文件數量
ReDim Preserve theFiles(currentSlot)
' 排序
' (8 表示 string)
If VarType(theFiles(0)(sortBy)) = 8 Then
If reverse Then kind = 1 Else kind = 2 ' 給字符排序
Else
If reverse Then kind = 3 Else kind = 4 '數字、時間。。。
End If
For i = fileCount TO 0 Step -1
minmax = theFiles(0)(sortBy)
minmaxSlot = 0
For j = 1 To i
Select Case kind
Case 1
mark = (strComp(theFiles(j)(sortBy), minmax, vbTextCompare) < 0)
Case 2
mark = (strComp(theFiles(j)(sortBy), minmax, vbTextCompare) > 0)
Case 3
mark = (theFiles(j)(sortBy) < minmax)
Case 4
mark = (theFiles(j)(sortBy) > minmax)
End Select
If mark Then
minmax = theFiles(j)(sortBy)
minmaxSlot = j
End If
Next
If minmaxSlot <> i Then
temp = theFiles(minmaxSlot)
theFiles(minmaxSlot) = theFiles(i)
theFiles(i) = temp
End If
Next
' 結束
%>
<FORM Name="doSort" Method="Get">
<INPUT Type=Hidden Name=priorSort Value="<% = priorSort %>">
<INPUT Type=Hidden Name=sortBy Value="-1">
</FORM>
<SCRIPT Language="JavaScript">
function reSort(which)
{
document.doSort.sortBy.value = which;
document.doSort.submit();
}
</SCRIPT>
<CENTER>
<FONT Size="+2">
顯示<% = (fileCount+1) %> 該目錄下的文件<% = path %>
</FONT>
<P>
單擊排序，再點一次反向排序
<P>
<TABLE Border=1 CellPadding=3>
<TR>
<TH><A HREF="javascript:reSort(0);">文件名</A></TH>
<TH><A HREF="javascript:reSort(1);">擴展名</A></TH>
<TH><A HREF="javascript:reSort(2);">類型</A></TH>
<TH><A HREF="javascript:reSort(3);">大小</A></TH>
<TH><A HREF="javascript:reSort(4);">建立時間</A></TH>
<TH><A HREF="javascript:reSort(5);">上次修改時間</A></TH>
<TH><A HREF="javascript:reSort(6);">上次存取時間</A></TH>
</TR>
<%
For i = 0 To fileCount
Response.Write "<TR>" & vbNewLine
For j = 0 To UBound(theFiles(i))
Response.Write " <TD>" & theFiles(i)(j) & "</TD>" & vbNewLine
Next
Response.Write "</TR>" & vbNewLine
Next
%>
</TABLE>
</BODY>
</HTML>

上一篇：送給搞采集的兄弟一個sql語句

下一篇：Session對象失效的客戶端解決方法