于是把我的收集整理后發(fā)出來(lái)給大家共享一下。
說(shuō)明：
收集整理： 隨風(fēng) @bbs.bathome.cn 2008-04-15
第一個(gè)代碼 作者：Will Sort 出自：cn-dos
第二、三、四、個(gè)代碼 作者：namejm 出自：cn-dos
第五個(gè)為 bat 結(jié)合 vbs 代碼，作者及出處都不詳。
其中第一及第五個(gè)代碼，輸入負(fù)數(shù)為：追溯指定日期以后的天數(shù)。
第二、三、四個(gè)代碼，未作測(cè)試，但輸入正整數(shù)是可以的。也就是追溯指定日期以前的天數(shù)。
代碼一、
作者：Will Sort
復(fù)制代碼 代碼如下:
:: DateDel2.bat - 刪除指定路徑下指定日數(shù)以前修改的文件
:: 作者：Will Sort - 2005-9-2 - CMD@WinXP 出自：cn-dos
:: 注意事項(xiàng)：變量 tian 為指定日數(shù)，昨天為1，前天為2，依次類推
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~0,10% sdays
rem 下行的%tian%代表天數(shù).
set /p tian= 請(qǐng)指定要追溯的天數(shù)：
set /a sdays-=tian
call :Day2Date %sdays% difdate
echo.&echo.
echo 指定的日期是： %date:~0,10%
echo.
echo %tian% 天前的日期是：%difdate%
echo.&pause
exit
:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF
:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
代碼二、
以下三個(gè)代碼作者全是 namejm
復(fù)制代碼 代碼如下:
:: 作者： namejm 榮譽(yù)版主 出自：cn-dos
@echo off
:: 求N天前的日期
:: 思路：
:: 模擬手工運(yùn)算，用日期數(shù)減去天數(shù)，差值為負(fù)時(shí)向高位借1。
:: 特點(diǎn)：
:: 代碼簡(jiǎn)潔，容易理解，速度快慢取決于指定的天數(shù)大小
:: 日期可以帶星期，但是，必須以年月日的順序排列
:: 年份必須是四位，否則會(huì)出錯(cuò)
@echo off
:Main
cls
set day=%date%
set days=0
echo.&echo.
echo 指定的日期是：%day%
echo.
set /p input= 請(qǐng)指定要追溯的天數(shù)：
setlocal enabledelayedexpansion
:: 提取日期
for /f "tokens=1-3 delims=-/. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100
)
set /a sd-=input
if %sd% leq 0 call :count
cls
echo.&echo.
echo 指定的日期是：%day%
echo.
set sm=0%sm%
set sd=0%sd%
echo %input% 天前的日期是：%sy%-%sm:~-2%-%sd:~-2%
pause>nul
goto Main
:count
set /a sm-=1
if !sm! equ 0 set /a sm=12, sy-=1
call :days
set /a sd+=days
if %sd% leq 0 goto count
goto :eof
:days
:: 獲取指定月份的總天數(shù)
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
set num=0
set str=31 %max% 31 30 31 30 31 31 30 31 30 31
for %%i in (%str%) do (
set /a num+=1
if %sm% equ !num! set days=%%i&goto :eof
)
goto :eof
123下一頁(yè)閱讀全文
