轉(zhuǎn)載自 nxhujiee最終編輯 LJ_SunTB批處理中的【預(yù)處理】
━━━━━━━━━━━━━━━━━━━━━━━━━━
如果你對(duì)脫字字符“^”的處理機(jī)制比較熟悉那么可以接著閱讀，否
則請(qǐng)先參考脫字字符的相關(guān)文章。
一、預(yù)處理究竟要做什么？
根據(jù)我的經(jīng)驗(yàn)，預(yù)處理要做的是變量值的替換和特殊符號(hào)的處理。究竟先執(zhí)行哪個(gè)操作呢，我認(rèn)為要先進(jìn)行變量值的替換。理由有三：
1、 從邏輯上看
set var=2&echo %var%
類(lèi)似于這樣的語(yǔ)句，如果說(shuō)先進(jìn)行特殊符號(hào)處理的話，勢(shì)必要先處理符號(hào)“&”，而“&”是用來(lái)連接兩條命令的，這樣一來(lái)該行就理所應(yīng)當(dāng)?shù)谋焕斫鉃閮删?，那么我們還要變量延遲干嘛。這里應(yīng)該是
先對(duì)變量var賦值，然后處理特殊符號(hào)“&”。
2、從運(yùn)行結(jié)果看
復(fù)制代碼 代碼如下:
@echo off
set var=^^^>
echo %var%
pause
這句“set var=^^^>”首先也會(huì)被預(yù)處理，預(yù)處理之后var的值為“^>”。
本例的輸出結(jié)果是“>”，因此可以證明系統(tǒng)先將變量的值替換為“^>”然后再處理特殊符號(hào)“^”。
3、從變量替換上看
復(fù)制代碼 代碼如下:
@echo off
set ^&var=hero
echo %&var%
pause
結(jié)果：顯示“hero”
這也說(shuō)明變量的替換先于特殊符號(hào)的處理。
二、啟動(dòng)了變量延遲之后預(yù)處理又是如何進(jìn)行呢？
我的看法是這樣的：如果語(yǔ)句中存在英文嘆號(hào)“!”則會(huì)被預(yù)處理兩次，其它情況仍然是預(yù)處理一次。由于脫字字符比較特殊，因此在此借助該符號(hào)寫(xiě)幾個(gè)例子說(shuō)明一下。
（一）
復(fù)制代碼 代碼如下:
@echo off
echo !^^^^^>
setlocal enabledelayedexpansion
echo !^^^^^>
pause
兩個(gè)echo語(yǔ)句的結(jié)果不同。下面做一下分析：
對(duì)于第一個(gè)echo語(yǔ)句，變量延遲沒(méi)有開(kāi)啟，進(jìn)行預(yù)處理的時(shí)候該句就被預(yù)處理為“echo !^^>”，這也就是輸出的結(jié)果。由此可見(jiàn)預(yù)處理只進(jìn)行了一次。
對(duì)于第二個(gè)echo語(yǔ)句，此時(shí)變量延遲開(kāi)啟，由于有“!”存在，首先進(jìn)行一次預(yù)處理得到“echo !^^>”，再進(jìn)行一次得到“echo ^>”，結(jié)果也是如此。
之所以沒(méi)有輸出嘆號(hào)，是因?yàn)殚_(kāi)啟了變量延遲，嘆號(hào)就變?yōu)榱颂厥夥?hào)。
（二）
復(fù)制代碼 代碼如下:
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!
pause
像這里的“echo !var!”不是沒(méi)有被預(yù)處理，而是被預(yù)處理了兩次。看下面的這段代碼就可以理解了。
復(fù)制代碼 代碼如下:
@echo off
setlocal enabledelayedexpansion
set var=hero
echo !var!^^^^^>
pause
運(yùn)行的結(jié)果為：“hero^>”。我們來(lái)分析一下，進(jìn)行第一次預(yù)處理時(shí)，由于“!var!”，因此先不替換變量值而進(jìn)行特殊符號(hào)的處理，處理完后就成了“echo !var!^^>”；之后再進(jìn)行一次預(yù)處理，
此時(shí)就要替換“!var!”了，處理完后就成了“echo hero^>”。
（三）
我們?cè)賮?lái)看看當(dāng)變量延遲開(kāi)啟時(shí)語(yǔ)句中不存在英文嘆號(hào)的情況。
復(fù)制代碼 代碼如下:
@echo off
echo ^^^^^>
setlocal enabledelayedexpansion
echo ^^^^^>
pause
@echo off
set var=hero
echo %var%^^^^^>
setlocal enabledelayedexpansion
echo %var%^^^^^>
pause
怎么樣，也就是說(shuō)如果沒(méi)有“!”就不會(huì)進(jìn)行第二次處理。
（四）
對(duì)于!!型，特殊符號(hào)的處理是在變量替換之前進(jìn)行的。
例、
復(fù)制代碼 代碼如下:
@echo off
setlocal enabledelayedexpansion
set ^&var=hero
echo !&var!
pause
這段代碼運(yùn)行結(jié)果是錯(cuò)誤的。
例、
復(fù)制代碼 代碼如下:
@echo off
setlocal enabledelayedexpansion
set var=^&
echo !var!
pause
這段代碼運(yùn)行結(jié)果是正確的。
（五）
既然都要處理符號(hào)，那么%%型和!!型的符號(hào)處理會(huì)不會(huì)是同一個(gè)過(guò)程？
（一）中的例子已經(jīng)可以說(shuō)明問(wèn)題，不過(guò)我還有例子可以證明。
例、
復(fù)制代碼 代碼如下:
@echo off
echo "^^^^^^^^"!!
setlocal enabledelayedexpansion
echo "^^^^^^^^"!!
pause
對(duì)于%%型，在符號(hào)處理時(shí)，不處理雙引號(hào)間的脫字字符；而對(duì)于!!型則相反。
三、call引出的一些問(wèn)題
（一）
call與脫字字符
例、
復(fù)制代碼 代碼如下:
@echo off
set /p var=<hero.txt
echo "%var%"
call echo "%var%"
pause
其中hero.txt中的內(nèi)容為8個(gè)脫字字符：^^^^^^^^
結(jié)果是：
"^^^^^^^^"
"^^^^^^^^^^^^^^^^"
請(qǐng)按任意鍵繼續(xù). . .
結(jié)果是否有些出乎意料？我們知道，系統(tǒng)在預(yù)處理時(shí)不會(huì)處理雙引號(hào)間的脫字字符，那就意味著是call命令將其后的脫字字符數(shù)量加了倍?？磥?lái)call命令和脫字字符還真有點(diǎn)“曖昧”。
例、
復(fù)制代碼 代碼如下:
@echo off
set /p var=<hero.txt
echo %var%
call echo %var%
pause
本例中變量var的值為8個(gè)“^”，運(yùn)行“call echo %var%”時(shí)，首先進(jìn)行變量替換把%var%替換為^^^^^^^^，再經(jīng)一次符號(hào)的處理變?yōu)閊^^^，此時(shí)由于call命令使得脫字字符數(shù)目增加一倍變?yōu)?個(gè)，然后再進(jìn)行
call本身的預(yù)處理，這樣結(jié)果就為4個(gè)“^”。
這樣就能解釋下面的代碼為什么會(huì)顯示4個(gè)“^”。
復(fù)制代碼 代碼如下:
@echo off
call call call call echo ^^^^^^^^
pause
（二）
call與其它特殊字符
這里所說(shuō)的“其它特殊字符”主要指&、>、|等。
這里請(qǐng)?jiān)试S我自定義兩個(gè)名詞：
主預(yù)處理過(guò)程：系統(tǒng)本身預(yù)處理過(guò)程的總稱(chēng)，其中包括了%%型和!!型。
次預(yù)處理過(guò)程：由于call命令引起的預(yù)處理過(guò)程的總稱(chēng)。
“其它特殊字符”是在主預(yù)處理過(guò)程中被系統(tǒng)識(shí)別的，而在次預(yù)處理
過(guò)程中對(duì)這些符號(hào)的識(shí)別是有問(wèn)題的。
例、
復(fù)制代碼 代碼如下:
@echo off
call echo hero!^&pause
pause
本例中，經(jīng)過(guò)主預(yù)處理過(guò)程，&被識(shí)別為普通字符，而在次預(yù)處理過(guò)程中符號(hào)&的識(shí)別將產(chǎn)生問(wèn)題。正如《命令行參考》中提到的--不要在call 命令中使用管道和重定向符號(hào)。（這倒不是說(shuō)call語(yǔ)句中不能使
用那些符號(hào)，而是這些符號(hào)不能作為參數(shù)傳遞給call命令。）
這也從某種程度上說(shuō)明某行語(yǔ)句的句子結(jié)構(gòu)（一條還是多條）和功能（是從定向輸出還是其它）是在主預(yù)處理過(guò)程中確定的。
以上所有內(nèi)容，只是我個(gè)人的看法，由于沒(méi)有官方文檔的支持，因此僅供參考。
那么我們學(xué)了以上種種內(nèi)容又有什么實(shí)際用途呢？我想，懂得了以上道理就可以寫(xiě)出更加個(gè)性化的代碼，同時(shí)也可以作為一種偽裝術(shù)在實(shí)際中應(yīng)用。
復(fù)制代碼 代碼如下:
@echo off
set ^&=setlocal enabledelayedexpansion
set ^^^^^hero=^^^^^&p
set ^au=^^^au
set ^^^^^^^^^=障眼法
%&%
set ^^^^^se=^^^se!
echo %^^^^%!%^^hero%!au%^se%
怎么樣，這段代碼能看明白嗎？
