vbs 解析json jsonp的方法

2020-06-26 18:38:55

字體：大中小

供稿：網(wǎng)友

昨天說(shuō)了下用 htmlfile 來(lái)解析 html，今天依然用他來(lái)解析，htmlfile 是一個(gè) COM 版的 BOM 和 DOM，所以解析 html, 執(zhí)行 js 完全不在話下，今天就繼續(xù)解析 json 和 jsonp 吧

我收集了三種常見(jiàn) json jsonp 的格式，因?yàn)楹芏嗳苏椅艺f(shuō)如何用正則提取某個(gè)字符串，我看了下，要么是json，要么是jsonp，

正則簡(jiǎn)直浪費(fèi)，比如那種空間里說(shuō)說(shuō)的數(shù)據(jù)，上百條的信息，你正則個(gè)P，而且還有回復(fù)里的格式也差不多的，所以最好的方法還是解析。

先來(lái)看看常見(jiàn)的三種吧：

酷我音樂(lè)用戶信息 json 格式

http://kzone.kuwo.cn/mlog/UserVal?uid=1237357&from=profile

{"work":4,"fans":275,"lp":"{/"id/":1237357,/"username/":/"亂碼/",/"pic/":/"http://img3.kuwo.cn/star/userhead/57/55/1315554310390_1237357m.jpg/"}","art":4,"album":1,"fortune":342402,"article":0,"workVideo":1,"care":195,"workAudio":3,"view":1312997,"playlist":0,"listen":278962,"collect":1}

拍拍手機(jī)查詢接口 jsonp 格式

http://virtual.paipai.com/extinfo/GetMobileProductInfo?mobile=13012345678&amount=10000&callname=cb

cb({mobile:'13012345678',province:'重慶',isp:'中國(guó)聯(lián)通',stock:'1',amount:'10000',maxprice:'0',minprice:'0'});

搜狐IP信息 js 格式

http://pv.sohu.com/cityjson

var returnCitySN = {"cip": "218.72.14.14", "cid": "330100", "cname": "浙江省杭州市"};

這幾種合適都可以通過(guò) htmlfile 來(lái)解析，但是方法稍微有點(diǎn)差異。

先來(lái)解析第一種 json 格式的吧。

Set html = CreateObject("htmlfile")

Set http = CreateObject("Msxml2.ServerXMLHTTP")

http.open "GET", "http://kzone.kuwo.cn/mlog/UserVal?uid=1237357&from=profile", False

http.send

strHtml = http.responseText ' 得到數(shù)據(jù)

Set window = html.parentWindow

window.execScript "var json = " & strHtml, "JScript" ' 解析 json

Set kuwo = window.json ' 獲取解析后的對(duì)象

WScript.Echo "訪問(wèn)量:", kuwo.view, " 財(cái)富:", kuwo.fortune

可以得到如下信息。

再來(lái)看看 jsonp 的解析，jsonp其實(shí)只是多了一個(gè)回調(diào)函數(shù)而已，所以我們自定義一個(gè)函數(shù)解析他就可以了。

Set html = CreateObject("htmlfile")

Set http = CreateObject("Msxml2.ServerXMLHTTP")

callback = "cb"

url = "http://virtual.paipai.com/extinfo/GetMobileProductInfo?mobile=13012345678&amount=10000&callname=" & callback

http.open "GET", url, False

http.send

strHtml = http.responseText ' 得到數(shù)據(jù)

' cb({mobile:'13012345678',province:'重慶',isp:'中國(guó)聯(lián)通',stock:'1',amount:'10000',maxprice:'0',minprice:'0'});

' 

' 得到的是這樣的數(shù)據(jù)，所以要處理下

strHtml = Split(strHtml, vbLf)(0) ' 取第一行

Set window = html.parentWindow

window.execScript "function " & callback & "(o){json=o}", "JScript" ' jsonp 回調(diào)函數(shù)、

window.execScript strHtml, "JScript" ' 解析 json

Set json = window.json ' 獲取解析后的對(duì)象

WScript.Echo json.mobile, json.isp, json.province

可以得到如下信息。

最后看下 js 格式解析，這個(gè)是最簡(jiǎn)單的，什么都不用做，但是你要知道他的變量名。

Set html = CreateObject("htmlfile")

Set http = CreateObject("Msxml2.ServerXMLHTTP")

http.open "GET", "http://pv.sohu.com/cityjson", False

http.send

strHtml = http.responseText ' 得到數(shù)據(jù)

' 得到 var returnCitySN = {"cip": "218.72.14.14", "cid": "330100", "cname": "浙江省杭州市"};

Set window = html.parentWindow

window.execScript strHtml, "JScript" ' 解析 js

Set js = window.returnCitySN ' 獲取解析后的對(duì)象

WScript.Echo js.cname, js.cip, js.cid