使用模板實現ASP代碼與頁面分離

2024-05-04 11:07:58

字體：大中小

來源：轉載

供稿：網友

每個進行過較大型的ASP-Web應用程序設計的開發人員大概都有如下的經歷：ASP代碼與頁面HTML混淆難分，業務邏輯與顯示方式絞合，使得代碼難以理解、難以修改；程序編寫必須在美工之后，成為項目瓶頸；整合的程序代碼和HTML靜態頁面時，花費大量的時間才能得到理想的效果，兼作了美工。的確，用腳本語言開發Web應用不容易將數據的處理和數據的顯示分開，但在多人合作的情況下，如果無法將數據和顯示分開，將大大影響開發的效率，專業分工的發揮。
　　其它的腳本語言，如JSP、PHP都有自己的解決方案，ASP的后一代產品ASP.NET也實現了代碼與頁面，似乎直接過渡到ASP是不錯的選擇。但是總有這樣或那樣的原因讓我們不能或暫時不能放棄ASP直奔.NET大營。從公司角度來看，轉換語言是一筆不少的投資，包括雇傭熟手.NET程序員、培訓原有程序員、開發工具的轉型、開發風格的轉型、界面風格轉變、接口風格、軟件架構、文檔、開發流程等等；這還意味著原有的代碼必須在新語言環境里重寫以實現最佳的效果和穩定性；同時將直接影響這段時間內項目的進度，更有可能導致個別程序員出走。由此看來在您決定轉換語言之前，在原基礎上尋求一種解決方案，才是最好的選擇。
　　PHP通過模板實現代碼與頁面，可供選擇的有FastTemplate、PHPLIB、Smarty等多種，其中PHPLIB的影響最大、使用最多。既然如此，我們直接把它搬到ASP來，對于同時使用PHP和ASP的公司還有很有好處：一、美工處理頁面時，不管將要套用PHP還是ASP，處理方式是一樣，無須經過培訓；二、程序員編寫代碼時，兩種語言間的思路接近或一致，相同功能在兩種語言實現時，只需拷貝過來略作修改即可，保證了工作效率和項目進度。

1、模板類的設計
　　實現代碼封裝成為模板類，即是為了與PHPLIB兼容，也使得代碼方便管理與擴展。
　　模板類要實現的目標為：從模板文件中讀入顯示的HTML代碼，將這些顯示代碼中需要動態數據的地方替換為ASP程序運算所得出的數據，然后按照一定的順序輸出。其中，替換的部分可以自由的設定。因此它必須完成如下任務：
·從模板文件中讀取顯示用的HTML代碼。
·將模板文件和實際生成的數據結合，生成輸出的結果。
·允許同時處理多個模板。
·允許模板的嵌套。
·允許對模板中的某個單獨的部分進行處理。

實現方法：
采用FSO讀取模板文件
采用正則替換實現模板文件和數據的結合
處理多個模板用數組存儲來實現。
模板的嵌套的實現主要的想法是：將模板和輸出（任何中間的分析結果）一視同仁，都可拿來做替換，即可實現。
單獨部分的處理的通過在模板文件中設定標注，然后在正則替換中結合標注來控制，實現部分替換。

2、模板類的實現
　　給出具體代碼之前，先把主要函數列出，用過PHPLIB的朋友應該對此很熟悉了：
　　1）Public Sub set_root(ByVal Value)　設定模板默認目錄
　　2）Public Sub set_file(ByVal handle,ByVal filename)　讀取文件
　　3）Public Sub set_var(ByVal Name, ByVal Value, ByVal Append)　設置映射數據-替換變量
　　4）Public Sub unset_var(ByVal Name)　取消數據映射
　　5）Public Sub set_block(ByVal Parent, ByVal BlockTag, ByVal Name)　設置數據塊
　　6）Public Sub set_unknowns(ByVal unknowns)　設定未指定映射的標記處理方式
　　7）Public Sub parse(ByVal Name, ByVal BlockTag, ByVal Append)　執行模板文件與數據的結合
　　8）Public Sub p(ByVal Name)　輸出處理結果

實現代碼：
<%
'=======================================================================
' CLASS NAME: kktTemplate ASP頁面模板對象
' DESIGN BY : 彭國輝
' DATE: 2004-07-05
' WEBSITE: http://kacarton.yeah.net/
' EMAIL: kacarton@sohu.com
'
' 本對象中使用了set_var、set_block等命名方法是為了兼容phplib
'=======================================================================

Class kktTemplate

Private m_FileName, m_Root, m_Unknowns, m_LastError, m_HaltOnErr
Private m_ValueList, m_BlockList
Private m_RegExp
' 構造函數
Private Sub Class_Initialize
Set m_ValueList = CreateObject("Scripting.Dictionary")
Set m_BlockList = CreateObject("Scripting.Dictionary")
set m_RegExp = New RegExp
m_RegExp.IgnoreCase = True
m_RegExp.Global = True
m_FileName = ""
m_Root = ""
m_Unknowns = "remove"
m_LastError = ""
m_HaltOnErr = true
End Sub

' 析構函數
Private Sub Class_Terminate
Set m_RegExp = Nothing
Set m_BlockMatches = Nothing
Set m_ValueMatches = nothing
End Sub

Public Property Get ClassName()
ClassName = "kktTemplate"
End Property

Public Property Get Version()
Version = "1.0"
End Property

Public Sub About()
Response.Write("kktTemplate ASP頁面模板類<br>" & vbCrLf &_
"程序設計：彭國輝 2004-07-05<br>" & vbCrLf &_
"個人網站：<a href='http://kacarton.yeah.net'>http://kacarton.yeah.net<;/a><br>" & vbCrLf &_
"電子郵件：<a href='mailto:kacarton@sohu.com'>kacarton@sohu.com</a><br>")
End Sub

'檢查目錄是否存在
Public Function FolderExist(ByVal path)
Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")
FolderExist = fso.FolderExists(Server.MapPath(path))
Set fso = Nothing
End Function
'讀取文件內容
Private Function LoadFile()
Dim Filename, fso, hndFile
Filename = m_Root
If Right(Filename, 1)<>"/" And Right(Filename, 1)<>"/" Then Filename = Filename & "/"
Filename = Server.MapPath(Filename & m_FileName)
Set fso = CreateObject("Scripting.FileSystemObject")
If Not fso.FileExists(Filename) Then ShowError("模板文件" & m_FileName & "不存在!")
set hndFile = fso.OpenTextFile(Filename)
LoadFile = hndFile.ReadAll
Set hndFile = Nothing
Set fso = Nothing
If LoadFile = "" Then ShowError("不能讀取模板文件" & m_FileName & "或文件為空!")
End Function

'處理錯誤信息
Private Sub ShowError(ByVal msg)
m_LastError = msg
Response.Write "<font color=red style='font-size;14px'><b>模板錯誤：" & msg & "</b></font><br>"
If m_HaltOnErr Then Response.End
End Sub

'設置模板文件默認目錄
'Ex: kktTemplate.set_root("/tmplate")
' kktTemplate.Root = "/tmplate"
' root = kktTemplate.get_root()
' root = kktTemplate.Root
'使用類似set_root這樣的命名方法是為了兼容phplib，以下將不再重復說明
Public Sub set_root(ByVal Value)
If Not FolderExist(Value) Then ShowError(Value & "不是有效目錄或目錄不存在!")
m_Root = Value
End Sub
Public Function get_root()
get_root = m_Root
End Function
Public Property Let Root(ByVal Value)
set_root(Value)
End Property
Public Property Get Root()
Root = m_Root
End Property

'設置模板文件
'Ex: kktTemplate.set_file("hndTpl", "index.htm")
'本類不支持多模板文件，handle為兼容phplib而保留
Public Sub set_file(ByVal handle,ByVal filename)
m_FileName = filename
m_BlockList.Add Handle, LoadFile()
End Sub
Public Function get_file()
get_file = m_FileName
End Function
' Public Property Let File(handle, filename)
' set_file handle, filename
' End Property
' Public Property Get File()
' File = m_FileName
' End Property

'設置對未指定的標記的處理方式，有keep、remove、comment三種
Public Sub set_unknowns(ByVal unknowns)
m_Unknowns = unknowns
End Sub
Public Function get_unknowns()
get_unknowns = m_Unknowns
End Function
Public Property Let Unknowns(ByVal unknown)
m_Unknowns = unknown
End Property
Public Property Get Unknowns()
Unknowns = m_Unknowns
End Property

Public Sub set_block(ByVal Parent, ByVal BlockTag, ByVal Name)
Dim Matches
m_RegExp.Pattern = "([/s/S.]*)"
If Not m_BlockList.Exists(Parent) Then ShowError("未指定的塊標記" & Parent)
set Matches = m_RegExp.Execute(m_BlockList.Item(Parent))
For Each Match In Matches
m_BlockList.Add BlockTag, Match.SubMatches(0)
m_BlockList.Item(Parent) = Replace(m_BlockList.Item(Parent), Match.Value, "{" & Name & "}")
Next
set Matches = nothing
End Sub

Public Sub set_var(ByVal Name, ByVal Value, ByVal Append)
Dim Val
If IsNull(Value) Then Val = "" Else Val = Value
If m_ValueList.Exists(Name) Then
If Append Then m_ValueList.Item(Name) = m_ValueList.Item(Name) & Val _
Else m_ValueList.Item(Name) = Val
Else
m_ValueList.Add Name, Value
End If
End Sub

Public Sub unset_var(ByVal Name)
If m_ValueList.Exists(Name) Then m_ValueList.Remove(Name)
End Sub

Private Function InstanceValue(ByVal BlockTag)
Dim keys, i
InstanceValue = m_BlockList.Item(BlockTag)
keys = m_ValueList.Keys
For i=0 To m_ValueList.Count-1
InstanceValue = Replace(InstanceValue, "{" & keys(i) & "}", m_ValueList.Item(keys(i)))
Next
End Function

Public Sub parse(ByVal Name, ByVal BlockTag, ByVal Append)
If Not m_BlockList.Exists(BlockTag) Then ShowError("未指定的塊標記" & Parent)
If m_ValueList.Exists(Name) Then
If Append Then m_ValueList.Item(Name) = m_ValueList.Item(Name) & InstanceValue(BlockTag) _
Else m_ValueList.Item(Name) = InstanceValue(BlockTag)
Else
m_ValueList.Add Name, InstanceValue(BlockTag)
End If
End Sub

Private Function finish(ByVal content)
Select Case m_Unknowns
Case "keep" finish = content
Case "remove"
m_RegExp.Pattern = "/{[^ /t/r/n}]+/}"
finish = m_RegExp.Replace(content, "")
Case "comment"
m_RegExp.Pattern = "/{([^ /t/r/n}]+)/}"
finish = m_RegExp.Replace(content, "")
Case Else finish = content
End Select
End Function

Public Sub p(ByVal Name)
If Not m_ValueList.Exists(Name) Then ShowError("不存在的標記" & Name)
Response.Write(finish(m_ValueList.Item(Name)))
End Sub
End Class
%>

3、使用例子
　　下面舉三個例子進行說明。
1)簡單的值替換
模板文件為myTemple.tpl，內容：
<html><title>ASP模板簡單替換</title><body>
祝賀！你贏了一輛{some_color}法拉利！
</body>

下面是ASP代碼（kktTemplate.inc.asp就是上面給出的模板類）：

<%
dim my_color, kkt
my_color = "紅色的"
set kkt = new kktTemplate '創建模板對象
kkt.set_file "hndKktTemp", "myTemple.tpl" '設置并讀取模板文件myTemple.tpl
kkt.set_var "some_color", my_color, false '設置模板變量 some_color = my_color的值
kkt.parse "out", "hndKktTemp", false '模板變量 out = 處理后的文件
kkt.p "out" '輸出out的內容
set kkt = nothing '銷毀模板對象
%>

執行后輸出為：
<html><title>ASP模板簡單替換</title><body>
祝賀！你贏了一輛紅色的法拉利！
</body>

2)循環塊演示例子
模板文件myTemple2.tpl：
<html><title>ASP模板－塊的演示</title><body>
<table cellspacing="2" border="1"><tr><td>下面的動物您喜歡哪一種</td></tr>

<tr><td><input type="radio" name="chk">{animal}</td></tr>

</table>
</body>

ASP代碼：

<%
dim animal, kkt, i
animal = Array("小豬","小狗","小強")
set kkt = new kktTemplate
kkt.set_file "hndKktTemp", "myTemple2.tpl"
kkt.set_block "hndKktTemp", "AnimalList", "list"
for i=0 to UBound(animal)
kkt.set_var "animal", animal(i), false
kkt.parse "list", "AnimalList", true
next
kkt.parse "out", "hndKktTemp", false
kkt.p "out"
set kkt = nothing
%>

執行結果：
<html><title>ASP模板－塊的演示</title><body>
<table cellspacing="2" border="1"><tr><td>下面的動物您喜歡哪一種</td></tr>
<tr><td><input type="radio" name="chk">小豬</td></tr>
<tr><td><input type="radio" name="chk">小狗</td></tr>
<tr><td><input type="radio" name="chk">小強</td></tr>
</table>
</body>

3)嵌套塊演示
模板文件myTemple3.tpl：
<html><title>ASP模板－嵌套塊演示</title>
<body><table width="400" border="1" bordercolor="#000000">
<tr><td><div align="center">{myname}測試</div></td></tr>
<tr><td>我的動植物園：</td> </tr>

<tr><td>{animal}</td></tr>

<tr><td> {plant}</td></tr>


</table>
</body>
</html>

ASP代碼：

<%
dim my_color, kkt, myname, animal, plant
set kkt = new kktTemplate
myname = "kktTemplate block test..."
animal = array("動物", "植物")
plant = array(array("小豬","小白","小強"), array("玫瑰","向日葵"))

kkt.set_file "hndKktTemp", "myTemple3.tpl"
kkt.set_var "myname", myname, false
kkt.set_block "hndKktTemp", "animalList", "a"
kkt.set_block "animalList", "plantList", "p"

for i=0 to UBound(animal)
kkt.set_var "animal", animal(i), False
kkt.unset_var "p"
'kkt.set_var "p", "", false
for j=0 to UBound(plant(i))
kkt.set_var "plant", plant(i)(j), false
kkt.parse "p", "plantList", true
next
kkt.parse "a", "animalList", true
next
kkt.parse "out", "hndKktTemp", false
kkt.p "out"
%>

執行結果：
<html><title>ASP模板－嵌套塊演示</title>
<body><table width="400" border="1" bordercolor="#000000">
<tr><td><div align="center">kktTemplate block test...測試</div></td></tr>
<tr><td>我的動植物園：</td> </tr>
<tr><td>動物</td></tr>
<tr><td> 小豬</td></tr>
<tr><td> 小白</td></tr>
<tr><td> 小強</td></tr>
<tr><td>植物</td></tr>
<tr><td> 玫瑰</td></tr>
<tr><td> 向日葵</td></tr>
</table>
</body>
</html>

本文提及的所有代碼可從此處下載：http://www.freewebs.com/kacarton/web/kktTemplate.rar(3.53K)

4、小結
　　本文主要介紹了基于ASP利用模板類實現代碼與頁面分離的方法，當然還有其它更好的解決方案。本文旨在拋磚引玉各位讀者、WEB開發參與進來，多提寶貴意見，多作交流，共同進步！

上一篇：ASP小偷(遠程數據獲取)程序入門教程

下一篇：ASP使用類概念實現模塊化