這個是腳本代碼[保存為etime.bat放在當前路徑下即可：

代碼如下:
:etime <begin_time> <end_time> <return>
rem 所測試任務的執行時間不超過1天 // 骨瘦如柴版
setlocal&set be=%~1:%~2&set cc=(%%d-%%a)*360000+(1%%e-1%%b)*6000+1%%f-1%%c&set dy=-8640000
for /f "delims=: tokens=1-6" %%a in ("%be:.=%")do endlocal&set/a %3=%cc%,%3+=%dy%*("%3>>31")&exit/b

計算兩個時間點差的函數批處理etime

今天興趣大法思考了好多bat的問題，以至于通宵
在論壇逛看到有個求時間差的"函數"被打攪調用地方不少(大都是測試代碼執行效率的)

代碼如下:
:time0
::計算時間差（封裝）
@echo off&setlocal&set /a n=0&rem code 隨風 @bbs.bathome.cn
for /f "tokens=1-8 delims=.: " %%a in ("%~1:%~2") do (
set /a n+=10%%a%%100*360000+10%%b%%100*6000+10%%c%%100*100+10%%d%%100
set /a n-=10%%e%%100*360000+10%%f%%100*6000+10%%g%%100*100+10%%h%%100)
set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100
set "ok=%s% 小時 %f% 分鐘 %m% 秒 %n% 毫秒"
endlocal&set %~3=%ok:-=%&goto :EOF

這個代碼的算法是統一找時間點凌晨0:00:00.00然后計算任何一個時間點到凌晨的時間差(單位跑秒)
然后任意兩個時間點求時間差就是他們相對凌晨時間點的時間數的差
對09這樣的非法8進制數的處理用到了一些技巧，還有兩個時間參數不分先后順序，可全可點，
但是這個代碼一行是可以省去的(既然是常被人掉用自然體積越小越好):

代碼如下:
@echo off&setlocal&set/a n=0&set "s=+:%~1^&echo -:%~2"
for /f "tokens=1-5 delims=.:" %%a in ('echo %s%') do (rem code 隨風 @bbs.bathome.cn
set/a n%%a=10%%b%%100*360000+10%%c%%100*6000+10%%d%%100*100+10%%e%%100)
set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100
set "ok=%s% 小時 %f% 分鐘 %m% 秒 %n% 毫秒"
endlocal&(if %3. equ . (echo %ok:-=%) else set %~3=%ok:-=%)&exit/b

再研究下，有更簡短的版本
這個代碼是我在cn-dos寫過的，今天再優化了下更簡短
代碼的算法深入一層：
用hmsw(各字母代表一個兩位數字)表示標準時間
我們記他到凌晨的相對時間數為Tx
Tx=hmsw時間點-0:00:00.00時間點=h*3600*100+m*60*100+100*s+w
hmsw 8位10進制數表示的時間數(單位0.01秒)就是hmsw跑秒
hmsw=w+100*s+10000*m+1000000*h
hmsw-Tx=640000*h+4000*m
所以Tx=hmsw-(640000*h+4000*m)=hmsw-4000*(160*h+m)
那么Tx_2-Tx_1=hmsw_2-hmsw_1-4000*(160*(h_2-h_1)+(m_2-m_1))
對與09這樣的非法8進制數我們給他們每個前面加上1就可以保證是十進制數又能保證差值不變
對于非同一天的時間(這種情況較少，除非你在接近0晨時調用)我們把用8640000-去替換負號
再用set/a賦值
就是下面代碼用到的算法