需要實現一個復制文件夾的功能，網上找到相關代碼，并做了改進，vbs腳本如下

CopyCount = CopyCount + XCopy(fso, "./1", "./2", True)
MsgBox "拷貝了" & CopyCount & "個文件!"

'********************************************************************
'* Function :     XCopy
'*
'* Purpose:  復制文件和目錄樹。
'*
'* Input:    fso            FileSystemObject 對象實例
'*           source         指定要復制的文件。
'*           destination    指定新文件的位置和/或名稱。
'*           overwrite      是否覆蓋已存在文件。 Ture 覆蓋， False 跳過
'*
'* Output:   返回復制的文件個數
'*
'********************************************************************
Function XCopy(fso, source, destination, overwrite)
    Dim s, d, f, l, CopyCount
    Set s = fso.GetFolder(source)

    If Not fso.FolderExists(destination) Then
        fso.CreateFolder destination
    End If
    Set d = fso.GetFolder(destination)

    CopyCount = 0
    For Each f In s.Files
        l = d.Path & "/" & f.Name
        If Not fso.FileExists(l) Or overwrite Then
            If fso.FileExists(l) Then
                fso.DeleteFile l, True
            End If
            f.Copy l, True
            CopyCount = CopyCount + 1
        End If
    Next

    For Each f In s.SubFolders
        CopyCount = CopyCount + XCopy(fso, f.Path, d.Path & "/" & f.Name, overwrite)
    Next

    XCopy = CopyCount
End Function

在腳本文件路徑建立一個文件夾，取名1，放入兩個文件，運行程序結果如下



vbs復制文件的代碼：

發表評論 共有條評論 用戶名: 密碼: 驗證碼: 匿名發表